Rules for integrands of the form u (((a+b ArcSech[c x]))^n)

1.  ∫(((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1.  ∫ArcSech[c x]dx

1:  ∫ArcSech[c x]dx

Reference: CRC 591, A&S 4.6.47

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)ArcSech[c x]==-(((Sqrt[1+c x]) (Sqrt[(1/(1+c x))]))/(x (Sqrt[1-(c^2) (x^2)])))

Basis: (∂_x)((Sqrt[1+c x])(Sqrt[(1/(1+c x))]))==0

Rule:

∫ArcSech[c x]dx  ⟶  x ArcSech[c x]+(Sqrt[1+c x])(Sqrt[(1/(1+c x))]) ∫(1/(Sqrt[1-(c^2) (x^2)]))dx

Program code:

Int[ArcSech[c_.*x_],x_Symbol] :=
  x*ArcSech[c*x] + Sqrt[1+c*x]*Sqrt[1/(1+c*x)]*Int[1/Sqrt[1-c^2*x^2],x] /;
FreeQ[c,x]

2:  ∫ArcCsch[c x]dx

Reference: CRC 594, A&S 4.6.46

Derivation: Integration by parts

Rule:

∫ArcCsch[c x]dx  ⟶  x ArcCsch[c x]+(1/c)∫(1/(x(Sqrt[1+(1/((c^2) (x^2)))])))dx

Program code:

Int[ArcCsch[c_.*x_],x_Symbol] :=
  x*ArcCsch[c*x] + 1/c*Int[1/(x*Sqrt[1+1/(c^2*x^2)]),x] /;
FreeQ[c,x]

2:  ∫(((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

Derivation: Integration by substitution

Basis: 1==-(1/c)Sech[ArcSech[c x]]Tanh[ArcSech[c x]] (∂_x)ArcSech[c x]

Rule: If  n∈(SuperPlus[ℤ]), then

∫(((a+b ArcSech[c x]))^n)dx  ⟶  -(1/c) Subst[∫(((a+b x))^n)Sech[x] Tanh[x]dx,x,ArcSech[c x]]

Program code:

Int[(a_.+b_.*ArcSech[c_.*x_])^n_,x_Symbol] :=
  -1/c*Subst[Int[(a+b*x)^n*Sech[x]*Tanh[x],x],x,ArcSech[c*x]] /;
FreeQ[{a,b,c,n},x] && IGtQ[n,0]

Int[(a_.+b_.*ArcCsch[c_.*x_])^n_,x_Symbol] :=
  -1/c*Subst[Int[(a+b*x)^n*Csch[x]*Coth[x],x],x,ArcCsch[c*x]] /;
FreeQ[{a,b,c,n},x] && IGtQ[n,0]

2.  ∫(((d x))^m)(((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1.  ∫(((d x))^m) (a+b ArcSech[c x])dx

1:  ∫((a+b ArcSech[c x])/x)dx

Derivation: Integration by substitution

Basis: ArcSech[z]==ArcCosh[(1/z)]

Basis: ((F[(1/x)])/x)==-Subst[((F[x])/x),x,(1/x)](∂_x)(1/x)

Rule:

∫((a+b ArcSech[c x])/x)dx  ⟶  ∫((a+b ArcCosh[(1/(c x))])/x)dx  ⟶  -Subst[∫((a+b ArcCosh[(x/c)])/x)dx,x,(1/x)]

Program code:

Int[(a_.+b_.*ArcSech[c_.*x_])/x_,x_Symbol] :=
  -Subst[Int[(a+b*ArcCosh[x/c])/x,x],x,1/x] /;
FreeQ[{a,b,c},x]

Int[(a_.+b_.*ArcCsch[c_.*x_])/x_,x_Symbol] :=
  -Subst[Int[(a+b*ArcSinh[x/c])/x,x],x,1/x] /;
FreeQ[{a,b,c},x]

2.  ∫(((d x))^m) (a+b ArcSech[c x])dx  when  m≠-1

1:  ∫(((d x))^m) (a+b ArcSech[c x])dx  when  m≠-1

Reference: CRC 593', A&S 4.6.58'

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcSech[c x])==-((b (Sqrt[(1/(1+c x))]))/(x (Sqrt[1-c x])))

Basis: (∂_x)((Sqrt[1+c x])(Sqrt[(1/(1+c x))]))==0

Note: Although (Sqrt[1-(c^2) (x^2)])==(Sqrt[1-c x])(Sqrt[1+c x]), leaving denominator factored allows for more cancellation with piecewise constant factor.

Rule: If  m≠-1, then

∫(((d x))^m) (a+b ArcSech[c x])dx  ⟶  (((((d x))^(m+1)) (a+b ArcSech[c x]))/(d (m+1)))+((b (Sqrt[1+c x]))/(m+1))(Sqrt[(1/(1+c x))]) ∫((((d x))^m)/((Sqrt[1-c x]) (Sqrt[1+c x])))dx

Program code:

Int[(d_.*x_)^m_.*(a_.+b_.*ArcSech[c_.*x_]),x_Symbol] :=
  (d*x)^(m+1)*(a+b*ArcSech[c*x])/(d*(m+1)) + 
  b*Sqrt[1+c*x]/(m+1)*Sqrt[1/(1+c*x)]*Int[(d*x)^m/(Sqrt[1-c*x]*Sqrt[1+c*x]),x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1]

2:  ∫(((d x))^m) (a+b ArcCsch[c x])dx  when  m≠-1

Reference: CRC 596, A&S 4.6.56

Derivation: Integration by parts

Rule: If  m≠-1, then

∫(((d x))^m) (a+b ArcCsch[c x])dx  ⟶  (((((d x))^(m+1)) (a+b ArcCsch[c x]))/(d (m+1)))+((b d)/(c(m+1)))∫((((d x))^(m-1))/(Sqrt[1+(1/((c^2) (x^2)))]))dx

Program code:

Int[(d_.*x_)^m_.*(a_.+b_.*ArcCsch[c_.*x_]),x_Symbol] :=
  (d*x)^(m+1)*(a+b*ArcCsch[c*x])/(d*(m+1)) + 
  b*d/(c*(m+1))*Int[(d*x)^(m-1)/Sqrt[1+1/(c^2*x^2)],x] /;
FreeQ[{a,b,c,d,m},x] && NeQ[m,-1]

2:  ∫(x^m) (((a+b ArcSech[c x]))^n)dx  when  n∈ℤ∧ m∈ℤ ∧ (n>0 ∨ m<-1)

Derivation: Integration by substitution

Basis: If  m∈ℤ, then (x^m) F[ArcSech[c x]]==-(1/(c^(m+1)))Subst[F[x] ((Sech[x])^(m+1))Tanh[x],x,ArcSech[c x]] (∂_x)ArcSech[c x]

Rule: If  n∈ℤ∧ m∈ℤ ∧ (n>0 ∨ m<-1), then

∫(x^m) (((a+b ArcSech[c x]))^n)dx  ⟶  -(1/(c^(m+1))) Subst[∫(((a+b x))^n)((Sech[x])^(m+1)) Tanh[x]dx,x,ArcSech[c x]]

Program code:

Int[x_^m_.*(a_.+b_.*ArcSech[c_.*x_])^n_,x_Symbol] :=
  -1/c^(m+1)*Subst[Int[(a+b*x)^n*Sech[x]^(m+1)*Tanh[x],x],x,ArcSech[c*x]] /;
FreeQ[{a,b,c},x] && IntegerQ[n] && IntegerQ[m] && (GtQ[n,0] || LtQ[m,-1])

Int[x_^m_.*(a_.+b_.*ArcCsch[c_.*x_])^n_,x_Symbol] :=
  -1/c^(m+1)*Subst[Int[(a+b*x)^n*Csch[x]^(m+1)*Coth[x],x],x,ArcCsch[c*x]] /;
FreeQ[{a,b,c},x] && IntegerQ[n] && IntegerQ[m] && (GtQ[n,0] || LtQ[m,-1])

3.  ∫(((d+e x))^m) (a+b ArcSech[c x])dx

1.  ∫(((d+e x))^m) (a+b ArcSech[c x])dx

1:  ∫((a+b ArcSech[c x])/(d+e x))dx

Derivation: Integration by parts

Basis: (1/(d+e x))==(1/e) (∂_x)(Log[1+((e-(Sqrt[-(c^2) (d^2)+(e^2)]))/(c d (e^(ArcSech[c x]))))]+Log[1+((e+(Sqrt[-(c^2) (d^2)+(e^2)]))/(c d (e^(ArcSech[c x]))))]-Log[1+(1/(e^(2 ArcSech[c x])))])

Basis: (∂_x)(a+b ArcSech[c x])==-((b (Sqrt[((1-c x)/(1+c x))]))/(x (1-c x)))

Rule:

∫((a+b ArcSech[c x])/(d+e x))dx  ⟶  
(((a+b ArcSech[c x]) Log[1+((e-(Sqrt[-(c^2) (d^2)+(e^2)]))/(c d (e^(ArcSech[c x]))))])/e)+(((a+b ArcSech[c x]) Log[1+((e+(Sqrt[-(c^2) (d^2)+(e^2)]))/(c d (e^(ArcSech[c x]))))])/e)-(((a+b ArcSech[c x]) Log[1+(1/(e^(2 ArcSech[c x])))])/e)+
(b/e) ∫(((Sqrt[((1-c x)/(1+c x))]) Log[1+((e-(Sqrt[-(c^2) (d^2)+(e^2)]))/(c d (e^(ArcSech[c x]))))])/(x (1-c x)))dx+(b/e) ∫(((Sqrt[((1-c x)/(1+c x))]) Log[1+((e+(Sqrt[-(c^2) (d^2)+(e^2)]))/(c d (e^(ArcSech[c x]))))])/(x (1-c x)))dx-(b/e) ∫(((Sqrt[((1-c x)/(1+c x))]) Log[1+(1/(e^(2 ArcSech[c x])))])/(x (1-c x)))dx

Program code:

Int[(a_.+b_.*ArcSech[c_.*x_])/(d_.+e_.*x_),x_Symbol] :=
  (a+b*ArcSech[c*x])*Log[1+(e-Sqrt[-c^2*d^2+e^2])/(c*d*E^ArcSech[c*x])]/e + 
  (a+b*ArcSech[c*x])*Log[1+(e+Sqrt[-c^2*d^2+e^2])/(c*d*E^ArcSech[c*x])]/e - 
  (a+b*ArcSech[c*x])*Log[1+1/E^(2*ArcSech[c*x])]/e + 
  b/e*Int[(Sqrt[(1-c*x)/(1+c*x)]*Log[1+(e-Sqrt[-c^2*d^2+e^2])/(c*d*E^ArcSech[c*x])])/(x*(1-c*x)),x] + 
  b/e*Int[(Sqrt[(1-c*x)/(1+c*x)]*Log[1+(e+Sqrt[-c^2*d^2+e^2])/(c*d*E^ArcSech[c*x])])/(x*(1-c*x)),x] - 
  b/e*Int[(Sqrt[(1-c*x)/(1+c*x)]*Log[1+1/E^(2*ArcSech[c*x])])/(x*(1-c*x)),x] /;
FreeQ[{a,b,c,d,e},x]

2:  ∫(((d+e x))^m)(a+b ArcSech[c x])dx  when  m≠-1

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcSech[c x])==-((b (Sqrt[1+c x]) (Sqrt[(1/(1+c x))]))/(x (Sqrt[1-(c^2) (x^2)])))

Basis: (∂_x)((Sqrt[1+c x])(Sqrt[(1/(1+c x))]))==0

Rule: If  m∈ℤ ∧ m≠-1, then

∫(((d+e x))^m)(a+b ArcSech[c x])dx  ⟶  (((((d+e x))^(m+1)) (a+b ArcSech[c x]))/(e(m+1)))+((b (Sqrt[1+c x]))/(e(m+1)))(Sqrt[(1/(1+c x))]) ∫((((d+e x))^(m+1))/(x (Sqrt[1-(c^2) (x^2)])))dx

Program code:

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcSech[c_.*x_]),x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*ArcSech[c*x])/(e*(m+1)) + 
  b*Sqrt[1+c*x]/(e*(m+1))*Sqrt[1/(1+c*x)]*Int[(d+e*x)^(m+1)/(x*Sqrt[1-c^2*x^2]),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[m,-1]

2.  ∫(((d+e x))^m) (a+b ArcCsch[c x])dx

1:  ∫((a+b ArcCsch[c x])/(d+e x))dx

Derivation: Integration by parts

Basis: (1/(d+e x))==(1/e) (∂_x)(Log[1-(((e-(Sqrt[(c^2) (d^2)+(e^2)])) (e^(ArcCsch[c x])))/(c d))]+Log[1-(((e+(Sqrt[(c^2) (d^2)+(e^2)])) (e^(ArcCsch[c x])))/(c d))]-Log[1-(e^(2 ArcCsch[c x]))])

Basis: (∂_x)(a+b ArcCsch[c x])==-(b/(c (x^2) (Sqrt[1+(1/((c^2) (x^2)))])))

Rule:

∫((a+b ArcCsch[c x])/(d+e x))dx  ⟶  
(((a+b ArcCsch[c x]) Log[1-(((e-(Sqrt[(c^2) (d^2)+(e^2)])) (e^(ArcCsch[c x])))/(c d))])/e)+(((a+b ArcCsch[c x]) Log[1-(((e+(Sqrt[(c^2) (d^2)+(e^2)])) (e^(ArcCsch[c x])))/(c d))])/e)-
(((a+b ArcCsch[c x]) Log[1-(e^(2 ArcCsch[c x]))])/e)+(b/(c e)) ∫((Log[1-(((e-(Sqrt[(c^2) (d^2)+(e^2)])) (e^(ArcCsch[c x])))/(c d))])/((x^2) (Sqrt[1+(1/((c^2) (x^2)))])))dx+
(b/(c e)) ∫((Log[1-(((e+(Sqrt[(c^2) (d^2)+(e^2)])) (e^(ArcCsch[c x])))/(c d))])/((x^2) (Sqrt[1+(1/((c^2) (x^2)))])))dx-(b/(c e)) ∫((Log[1-(e^(2 ArcCsch[c x]))])/((x^2) (Sqrt[1+(1/((c^2) (x^2)))])))dx

Program code:

Int[(a_.+b_.*ArcCsch[c_.*x_])/(d_.+e_.*x_),x_Symbol] :=
  (a+b*ArcCsch[c*x])*Log[1-(e-Sqrt[c^2*d^2+e^2])*E^ArcCsch[c*x]/(c*d)]/e + 
  (a+b*ArcCsch[c*x])*Log[1-(e+Sqrt[c^2*d^2+e^2])*E^ArcCsch[c*x]/(c*d)]/e - 
  (a+b*ArcCsch[c*x])*Log[1-E^(2*ArcCsch[c*x])]/e + 
  b/(c*e)*Int[Log[1-(e-Sqrt[c^2*d^2+e^2])*E^ArcCsch[c*x]/(c*d)]/(x^2*Sqrt[1+1/(c^2*x^2)]),x] + 
  b/(c*e)*Int[Log[1-(e+Sqrt[c^2*d^2+e^2])*E^ArcCsch[c*x]/(c*d)]/(x^2*Sqrt[1+1/(c^2*x^2)]),x] - 
  b/(c*e)*Int[Log[1-E^(2*ArcCsch[c*x])]/(x^2*Sqrt[1+1/(c^2*x^2)]),x] /;
FreeQ[{a,b,c,d,e},x]

2:  ∫(((d+e x))^m)(a+b ArcCsch[c x])dx  when  m≠-1

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcCsch[c x])==-(b/(c (x^2) (Sqrt[1+(1/((c^2) (x^2)))])))

Rule: If  m≠-1, then

∫(((d+e x))^m)(a+b ArcCsch[c x])dx  ⟶  (((((d+e x))^(m+1)) (a+b ArcCsch[c x]))/(e(m+1)))+(b/(c e(m+1)))∫((((d+e x))^(m+1))/((x^2) (Sqrt[1+(1/((c^2) (x^2)))])))dx

Program code:

Int[(d_.+e_.*x_)^m_.*(a_.+b_.*ArcCsch[c_.*x_]),x_Symbol] :=
  (d+e*x)^(m+1)*(a+b*ArcCsch[c*x])/(e*(m+1)) + 
  b/(c*e*(m+1))*Int[(d+e*x)^(m+1)/(x^2*Sqrt[1+1/(c^2*x^2)]),x] /;
FreeQ[{a,b,c,d,e,m},x] && NeQ[m,-1]

4.  ∫(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1.  ∫(((d+e (x^2)))^p) (a+b ArcSech[c x])dx  when  p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ])

1:  ∫(((d+e (x^2)))^p) (a+b ArcSech[c x])dx  when  p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ])

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcSech[c x])==-((b(Sqrt[(1/(1+c x))]))/(x (Sqrt[1-c x])))

Basis: (∂_x)((Sqrt[(1/(1+c x))]) (Sqrt[1+c x]))==0

Note: If  p+(1/2)∈ℤ, then the terms of ∫(((d+e (x^2)))^p)dx times (∂_x)(a+b ArcSech[c x]) are of an easily integrable form.

Rule: If  p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ]), let u=∫(((d+e (x^2)))^p)dx, then

∫(((d+e (x^2)))^p) (a+b ArcSech[c x])dx  ⟶  u (a+b ArcSech[c x])+b(Sqrt[1+c x])(Sqrt[(1/(1+c x))]) ∫(u/(x(Sqrt[1-c x])(Sqrt[1+c x])))dx

Program code:

Int[(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcSech[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^p,x]},  
  Dist[(a+b*ArcSech[c*x]),u,x] + b*Sqrt[1+c*x]*Sqrt[1/(1+c*x)]*Int[SimplifyIntegrand[u/(x*Sqrt[1-c*x]*Sqrt[1+c*x]),x],x]] /;
FreeQ[{a,b,c,d,e},x] && (IGtQ[p,0] || ILtQ[p+1/2,0])

2:  ∫(((d+e (x^2)))^p) (a+b ArcCsch[c x])dx  when  p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ])

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcCsch[c x])==((b c)/((Sqrt[-(c^2) (x^2)]) (Sqrt[-1-(c^2) (x^2)])))

Basis: (∂_x)(x/(Sqrt[-(c^2) (x^2)]))==0

Note: If p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ]), then ∫(((d+e (x^2)))^p)dx is expressible as an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If  p∈(SuperPlus[ℤ])∨ p+(1/2)∈(SuperMinus[ℤ]), let u=∫(((d+e (x^2)))^p)dx, then

∫(((d+e (x^2)))^p) (a+b ArcCsch[c x])dx  ⟶  u (a+b ArcCsch[c x])-b c∫(u/((Sqrt[-(c^2) (x^2)]) (Sqrt[-1-(c^2) (x^2)])))dx  ⟶  u (a+b ArcCsch[c x])-((b c x)/(Sqrt[-(c^2) (x^2)]))∫(u/(x(Sqrt[-1-(c^2) (x^2)])))dx

Program code:

Int[(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcCsch[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^2)^p,x]},  
  Dist[(a+b*ArcCsch[c*x]),u,x] - b*c*x/Sqrt[-c^2*x^2]*Int[SimplifyIntegrand[u/(x*Sqrt[-1-c^2*x^2]),x],x]] /;
FreeQ[{a,b,c,d,e},x] && (IGtQ[p,0] || ILtQ[p+1/2,0])

2:  ∫(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ p∈ℤ

Derivation: Integration by substitution

Basis: ArcSech[z]==ArcCosh[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  n∈(SuperPlus[ℤ])∧ p∈ℤ, then

∫(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  ⟶  ∫((((1/x)))^(-2p))(((e+(d/(x^2))))^p) (((a+b ArcCosh[(1/(c x))]))^n)dx
  ⟶  -Subst[∫(((((e+d (x^2)))^p) (((a+b ArcCosh[(x/c)]))^n))/(x^(2(p+1))))dx,x,(1/x)]

Program code:

Int[(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcSech[c_.*x_])^n_.,x_Symbol] :=
  -Subst[Int[(e+d*x^2)^p*(a+b*ArcCosh[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && IntegerQ[p]

Int[(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcCsch[c_.*x_])^n_.,x_Symbol] :=
  -Subst[Int[(e+d*x^2)^p*(a+b*ArcSinh[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && IntegerQ[p]

3.  ∫(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p+(1/2)∈ℤ

1:  ∫(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p+(1/2)∈ℤ ∧ e>0 ∧ d<0

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[d+e (x^2)])/(x (Sqrt[e+(d/(x^2))])))==0

Basis: ArcSech[z]==ArcCosh[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Basis: If  e>0 ∧ d<0, then ((Sqrt[d+e (x^2)])/(Sqrt[e+(d/(x^2))]))==(Sqrt[(x^2)])

Rule: If  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p+(1/2)∈ℤ ∧ e>0 ∧ d<0, then

∫(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  ⟶  ((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))∫((((1/x)))^(-2p))(((e+(d/(x^2))))^p) (((a+b ArcCosh[(1/(c x))]))^n)dx
  ⟶  -((Sqrt[(x^2)])/x)Subst[∫(((((e+d (x^2)))^p) (((a+b ArcCosh[(x/c)]))^n))/(x^(2(p+1))))dx,x,(1/x)]

Program code:

Int[(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcSech[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[x^2]/x*Subst[Int[(e+d*x^2)^p*(a+b*ArcCosh[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[p+1/2] && GtQ[e,0] && LtQ[d,0]

Int[(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcCsch[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[x^2]/x*Subst[Int[(e+d*x^2)^p*(a+b*ArcSinh[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[e-c^2*d,0] && IntegerQ[p+1/2] && GtQ[e,0] && LtQ[d,0]

2:  ∫(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ p+(1/2)∈ℤ ∧ ¬(e>0 ∧ d<0)

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[d+e (x^2)])/(x (Sqrt[e+(d/(x^2))])))==0

Basis: ArcSech[z]==ArcCosh[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  (c^2)d+e==0 ∧ p+(1/2)∈ℤ ∧ ¬(e>0 ∧ d<0), then

∫(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  ⟶  ((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))∫((((1/x)))^(-2p))(((e+(d/(x^2))))^p) (((a+b ArcCosh[(1/(c x))]))^n)dx
  ⟶  -((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))Subst[∫(((((e+d (x^2)))^p) (((a+b ArcCosh[(x/c)]))^n))/(x^(2(p+1))))dx,x,(1/x)]

Program code:

Int[(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcSech[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[d+e*x^2]/(x*Sqrt[e+d/x^2])*Subst[Int[(e+d*x^2)^p*(a+b*ArcCosh[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[p+1/2] && Not[GtQ[e,0] && LtQ[d,0]]

Int[(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcCsch[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[d+e*x^2]/(x*Sqrt[e+d/x^2])*Subst[Int[(e+d*x^2)^p*(a+b*ArcSinh[x/c])^n/x^(2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[e-c^2*d,0] && IntegerQ[p+1/2] && Not[GtQ[e,0] && LtQ[d,0]]

5.  ∫(((f x))^m)(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])

1.  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSech[c x])dx  when  
			(p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ]))

1.  ∫x(((d+e (x^2)))^p) (a+b ArcSech[c x])dx  when  p≠-1

1:  ∫x(((d+e (x^2)))^p) (a+b ArcSech[c x])dx  when  p≠-1

Derivation: Integration by parts and piecewise constant extraction

Basis: x(((d+e (x^2)))^p)==(∂_x)((((d+e (x^2)))^(p+1))/(2 e (p+1)))

Basis: (∂_x)(a+b ArcSech[c x])==-((b (Sqrt[(1/(1+c x))]))/(x (Sqrt[1-c x])))

Basis: (∂_x)((Sqrt[1+c x])(Sqrt[(1/(1+c x))]))==0

Note: Although (Sqrt[1-(c^2) (x^2)])==(Sqrt[1-c x])(Sqrt[1+c x]), leaving denominator factored allows for more cancellation with piecewise constant factor.

Rule: If  p≠-1, then

∫x(((d+e (x^2)))^p) (a+b ArcSech[c x])dx  ⟶  (((((d+e (x^2)))^(p+1))(a+b ArcSech[c x]))/(2 e (p+1)))+((b(Sqrt[1+c x]))/(2 e (p+1)))(Sqrt[(1/(1+c x))])∫((((d+e (x^2)))^(p+1))/(x (Sqrt[1-c x]) (Sqrt[1+c x])))dx

Program code:

Int[x_*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcSech[c_.*x_]),x_Symbol] :=
  (d+e*x^2)^(p+1)*(a+b*ArcSech[c*x])/(2*e*(p+1)) + 
  b*Sqrt[1+c*x]/(2*e*(p+1))*Sqrt[1/(1+c*x)]*Int[(d+e*x^2)^(p+1)/(x*Sqrt[1-c*x]*Sqrt[1+c*x]),x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[p,-1]

2:  ∫x(((d+e (x^2)))^p) (a+b ArcCsch[c x])dx  when  p≠-1

Derivation: Integration by parts and piecewise constant extraction

Basis: x(((d+e (x^2)))^p)==(∂_x)((((d+e (x^2)))^(p+1))/(2 e (p+1)))

Basis: (∂_x)(a+b ArcCsch[c x])==((b c)/((Sqrt[-(c^2) (x^2)]) (Sqrt[-1-(c^2) (x^2)])))

Basis: (∂_x)(x/(Sqrt[-(c^2) (x^2)]))==0

Rule: If  p≠-1, then

∫x(((d+e (x^2)))^p) (a+b ArcCsch[c x])dx  ⟶  (((((d+e (x^2)))^(p+1))(a+b ArcCsch[c x]))/(2 e (p+1)))-((b c)/(2 e (p+1)))∫((((d+e (x^2)))^(p+1))/((Sqrt[-(c^2) (x^2)]) (Sqrt[-1-(c^2) (x^2)])))dx
  ⟶  (((((d+e (x^2)))^(p+1))(a+b ArcCsch[c x]))/(2 e (p+1)))-((b c x)/(2 e (p+1)(Sqrt[-(c^2) (x^2)])))∫((((d+e (x^2)))^(p+1))/(x(Sqrt[-1-(c^2) (x^2)])))dx

Program code:

Int[x_*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcCsch[c_.*x_]),x_Symbol] :=
  (d+e*x^2)^(p+1)*(a+b*ArcCsch[c*x])/(2*e*(p+1)) - 
  b*c*x/(2*e*(p+1)*Sqrt[-c^2*x^2])*Int[(d+e*x^2)^(p+1)/(x*Sqrt[-1-c^2*x^2]),x] /;
FreeQ[{a,b,c,d,e,p},x] && NeQ[p,-1]

2.  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSech[c x])dx  when  
				(p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ]))

1:  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSech[c x])dx  when  
					(p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ]))

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcSech[c x])==-((b (Sqrt[(1/(1+c x))]))/(x (Sqrt[1-c x])))

Basis: (∂_x)((Sqrt[1+c x])(Sqrt[(1/(1+c x))]))==0

Note: Although (Sqrt[1-(c^2) (x^2)])==(Sqrt[1-c x])(Sqrt[1+c x]), leaving denominator factored allows for more cancellation with piecewise constant factor.

Note: If (p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ])),
	then ∫(((f x))^m)(((d+e (x^2)))^p)dx is expressible as an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If (p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ])), let u=∫(((f x))^m)(((d+e (x^2)))^p)dx, then

∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcSech[c x])dx  ⟶  u (a+b ArcSech[c x])+b(Sqrt[1+c x])(Sqrt[(1/(1+c x))]) ∫(u/(x (Sqrt[1-c x]) (Sqrt[1+c x])))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcSech[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^p,x]},  
  Dist[(a+b*ArcSech[c*x]),u,x] + b*Sqrt[1+c*x]*Sqrt[1/(1+c*x)]*Int[SimplifyIntegrand[u/(x*Sqrt[1-c*x]*Sqrt[1+c*x]),x],x]] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && (
  IGtQ[p,0] && Not[ILtQ[(m-1)/2,0] && GtQ[m+2*p+3,0]] || 
  IGtQ[(m+1)/2,0] && Not[ILtQ[p,0] && GtQ[m+2*p+3,0]] || 
  ILtQ[(m+2*p+1)/2,0] && Not[ILtQ[(m-1)/2,0]])

2:  ∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcCsch[c x])dx  when  
					(p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ]))

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcCsch[c x])==((b c)/((Sqrt[-(c^2) (x^2)]) (Sqrt[-1-(c^2) (x^2)])))

Basis: (∂_x)(x/(Sqrt[-(c^2) (x^2)]))==0

Note: If (p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ])),
	then ∫(((f x))^m)(((d+e (x^2)))^p)dx is expressible as an algebraic function not involving logarithms, inverse trig or inverse hyperbolic functions.

Rule: If (p∈(SuperPlus[ℤ])∧ ¬(((m-1)/2)∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+1)/2)∈(SuperPlus[ℤ])∧ ¬(p∈(SuperMinus[ℤ])∧ m+2p+3>0))∨(((m+2p+1)/2)∈(SuperMinus[ℤ])∧ ((m-1)/2)∉(SuperMinus[ℤ])), let u=∫(((f x))^m)(((d+e (x^2)))^p)dx, then

∫(((f x))^m)(((d+e (x^2)))^p) (a+b ArcCsch[c x])dx  ⟶  u (a+b ArcCsch[c x])-b c∫(u/((Sqrt[-(c^2) (x^2)]) (Sqrt[-1-(c^2) (x^2)])))dx  ⟶  u (a+b ArcCsch[c x])-((b c x)/(Sqrt[-(c^2) (x^2)]))∫(u/(x(Sqrt[-1-(c^2) (x^2)])))dx

Program code:

Int[(f_.*x_)^m_.*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcCsch[c_.*x_]),x_Symbol] :=
  With[{u=IntHide[(f*x)^m*(d+e*x^2)^p,x]},  
  Dist[(a+b*ArcCsch[c*x]),u,x] - b*c*x/Sqrt[-c^2*x^2]*Int[SimplifyIntegrand[u/(x*Sqrt[-1-c^2*x^2]),x],x]] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && (
  IGtQ[p,0] && Not[ILtQ[(m-1)/2,0] && GtQ[m+2*p+3,0]] || 
  IGtQ[(m+1)/2,0] && Not[ILtQ[p,0] && GtQ[m+2*p+3,0]] || 
  ILtQ[(m+2*p+1)/2,0] && Not[ILtQ[(m-1)/2,0]] )

2:  ∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  when n∈(SuperPlus[ℤ])∧ (m|p)∈ℤ

Derivation: Integration by substitution

Basis: ArcSech[z]==ArcCosh[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If n∈(SuperPlus[ℤ])∧ (m|p)∈ℤ, then

∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  ⟶  ∫((((1/x)))^(-m-2p))(((e+(d/(x^2))))^p) (((a+b ArcCosh[(1/(c x))]))^n)dx
  ⟶  -Subst[∫(((((e+d (x^2)))^p)(((a+b ArcCosh[(x/c)]))^n))/(x^(m+2 (p+1))))dx,x,(1/x)]

Program code:

Int[x_^m_.*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcSech[c_.*x_])^n_.,x_Symbol] :=
  -Subst[Int[(e+d*x^2)^p*(a+b*ArcCosh[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && IntegersQ[m,p]

Int[x_^m_.*(d_.+e_.*x_^2)^p_.*(a_.+b_.*ArcCsch[c_.*x_])^n_.,x_Symbol] :=
  -Subst[Int[(e+d*x^2)^p*(a+b*ArcSinh[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && IntegersQ[m,p]

3.  ∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2) d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ

1:  ∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2)d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ ∧ e>0 ∧ d<0

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[d+e (x^2)])/(x (Sqrt[e+(d/(x^2))])))==0

Basis: ArcSech[z]==ArcCosh[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Basis: If  e>0 ∧ d<0, then ((Sqrt[d+e (x^2)])/(Sqrt[e+(d/(x^2))]))==(Sqrt[(x^2)])

Rule: If  n∈(SuperPlus[ℤ])∧ (c^2)d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ ∧ e>0 ∧ d<0, then

∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  ⟶  ((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))∫((((1/x)))^(-m-2p))(((e+(d/(x^2))))^p) (((a+b ArcCosh[(1/(c x))]))^n)dx
  ⟶  -((Sqrt[(x^2)])/x)Subst[∫(((((e+d (x^2)))^p) (((a+b ArcCosh[(x/c)]))^n))/(x^(m+2 (p+1))))dx,x,(1/x)]

Program code:

Int[x_^m_.*(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcSech[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[x^2]/x*Subst[Int[(e+d*x^2)^p*(a+b*ArcCosh[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[m] && IntegerQ[p+1/2] && GtQ[e,0] && LtQ[d,0]

Int[x_^m_.*(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcCsch[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[x^2]/x*Subst[Int[(e+d*x^2)^p*(a+b*ArcSinh[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[e-c^2*d,0] && IntegerQ[m] && IntegerQ[p+1/2] && GtQ[e,0] && LtQ[d,0]

2:  ∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  when  n∈(SuperPlus[ℤ])∧ (c^2)d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ ∧ ¬(e>0 ∧ d<0)

Derivation: Piecewise constant extraction and integration by substitution

Basis: (∂_x)((Sqrt[d+e (x^2)])/(x (Sqrt[e+(d/(x^2))])))==0

Basis: ArcSech[z]==ArcCosh[(1/z)]

Basis: F[(1/x)]==-Subst[((F[x])/(x^2)),x,(1/x)](∂_x)(1/x)

Rule: If  n∈(SuperPlus[ℤ])∧ (c^2)d+e==0 ∧ m∈ℤ ∧ p+(1/2)∈ℤ ∧ ¬(e>0 ∧ d<0), then

∫(x^m)(((d+e (x^2)))^p) (((a+b ArcSech[c x]))^n)dx  ⟶  ((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))∫((((1/x)))^(-m-2p))(((e+(d/(x^2))))^p) (((a+b ArcCosh[(1/(c x))]))^n)dx
  ⟶  -((Sqrt[d+e (x^2)])/(x(Sqrt[e+(d/(x^2))])))Subst[∫(((((e+d (x^2)))^p)(((a+b ArcCosh[(x/c)]))^n))/(x^(m+2 (p+1))))dx,x,(1/x)]

Program code:

Int[x_^m_.*(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcSech[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[d+e*x^2]/(x*Sqrt[e+d/x^2])*Subst[Int[(e+d*x^2)^p*(a+b*ArcCosh[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[c^2*d+e,0] && IntegerQ[m] && IntegerQ[p+1/2] && Not[GtQ[e,0] && LtQ[d,0]]

Int[x_^m_.*(d_.+e_.*x_^2)^p_*(a_.+b_.*ArcCsch[c_.*x_])^n_.,x_Symbol] :=
  -Sqrt[d+e*x^2]/(x*Sqrt[e+d/x^2])*Subst[Int[(e+d*x^2)^p*(a+b*ArcSinh[x/c])^n/x^(m+2*(p+1)),x],x,1/x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[n,0] && EqQ[e-c^2*d,0] && IntegerQ[m] && IntegerQ[p+1/2] && Not[GtQ[e,0] && LtQ[d,0]]

6.  ∫u (a+b ArcSech[c x])dx  when  ∫udx  is free of inverse functions

1:  ∫u (a+b ArcSech[c x])dx  when  ∫udx  is free of inverse functions

Derivation: Integration by parts and piecewise constant extraction

Basis: (∂_x)(a+b ArcSech[c x])==-(b/(c (x^2)(Sqrt[-1+(1/(c x))])(Sqrt[1+(1/(c x))])))

Basis: (∂_x)((Sqrt[1-(c^2) (x^2)])/(x (Sqrt[-1+(1/(c x))]) (Sqrt[1+(1/(c x))])))==0

Rule: Let  v->∫udx, if v is free of inverse functions, then

∫u (a+b ArcSech[c x])dx  ⟶  v (a+b ArcSech[c x])+(b/c) ∫(v/((x^2) (Sqrt[-1+(1/(c x))]) (Sqrt[1+(1/(c x))])))dx
  ⟶  v (a+b ArcSech[c x])+((b(Sqrt[1-(c^2) (x^2)]))/(c x (Sqrt[-1+(1/(c x))]) (Sqrt[1+(1/(c x))])))∫(v/(x (Sqrt[1-(c^2) (x^2)])))dx

Program code:

Int[u_*(a_.+b_.*ArcSech[c_.*x_]),x_Symbol] :=
  With[{v=IntHide[u,x]},  
  Dist[(a+b*ArcSech[c*x]),v,x] + 
  b*Sqrt[1-c^2*x^2]/(c*x*Sqrt[-1+1/(c*x)]*Sqrt[1+1/(c*x)])*
    Int[SimplifyIntegrand[v/(x*Sqrt[1-c^2*x^2]),x],x] /;
 InverseFunctionFreeQ[v,x]] /;
FreeQ[{a,b,c},x]

2:  ∫u (a+b ArcCsch[c x])dx  when  ∫udx  is free of inverse functions

Derivation: Integration by parts

Basis: (∂_x)(a+b ArcCsch[c x])==-(b/(c (x^2) (Sqrt[1+(1/((c^2) (x^2)))])))

Rule: Let  v==∫ udx, if v is free of inverse functions, then

∫u (a+b ArcCsch[c x])dx  ⟶  v (a+b ArcCsch[c x])+(b/c) ∫(v/((x^2) (Sqrt[1+(1/((c^2) (x^2)))])))dx

Program code:

Int[u_*(a_.+b_.*ArcCsch[c_.*x_]),x_Symbol] :=
  With[{v=IntHide[u,x]},  
  Dist[(a+b*ArcCsch[c*x]),v,x] + 
  b/c*Int[SimplifyIntegrand[v/(x^2*Sqrt[1+1/(c^2*x^2)]),x],x] /;
 InverseFunctionFreeQ[v,x]] /;
FreeQ[{a,b,c},x]

X:  ∫u (((a+b ArcSech[c x]))^n)dx

Rule:

∫u(((a+b ArcSech[c x]))^n)dx  ⟶  ∫u(((a+b ArcSech[c x]))^n)dx

Program code:

Int[u_.*(a_.+b_.*ArcSech[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcSech[c*x])^n,x] /;
FreeQ[{a,b,c,n},x]

Int[u_.*(a_.+b_.*ArcCsch[c_.*x_])^n_.,x_Symbol] :=
  Unintegrable[u*(a+b*ArcCsch[c*x])^n,x] /;
FreeQ[{a,b,c,n},x]